プログラム開発関連

//日本語の変数の事例(金額計算)

項目1="単価を入力してください。"
項目2="単価は？ "
単価=入力データ(項目1,項目2)

項目1="数量を入力してください。"
項目2="数量は？ "
数量=入力データ(項目1,項目2)

金額 = 単価 * 数量
print "金額=単価*数量 の結果は、" + 金額 + "円です。"


//データ入力用のサブルーチン。
function 入力データ(項目1,項目2)
    while true 
        入力 = input(項目1)
        ifb 入力 <> "" then                 //入力がないとき、入力指示を繰返す。
            print 項目2+入力+"円"
                //MsgBox を表示して、Yes のときブロックを抜ける。
            if MsgBox("入力よろしいか？", BTN_YES or BTN_NO) = BTN_YES then break 
        endif
    wend
    result=入力
fend

// マウス、キーボード入力をブロックする
StopForm(False)       // Stopウィンドウは出さない
LockHard(True)

//起動中のExcelを、COMとして「Excel」という名前のIDにして、取得する
//以下、このCOMのIDを使って、Excelを操作します。
Excel=GetActiveOLEObj("Excel.Application")
//COMを使って、開いているExcelのシート数を取得
シート数=Excel.Worksheets.Count

//一方、Excel画面というIDで、ウインドウズの画面として、Excelを取得します。
Excel画面=GetId("Microsoft Excel")

//エディタ(サクラエディタ)を起動する
エディタ = GetId("(無題) - sakura")
ifb エディタ < 0                     // 存在してなければ起動
    エディタ = EXEC("C:\Tool\テキストエディタ\sakura.exe")
endif
sleep(0.01)    //0.01秒待たせます

For i=1 to シート数
    //Excelのシートを順に開いて、全画面を選択してコピーする
    Excel.Worksheets(i).activate
    Excel.Cells.Copy
    //Excelのシート名も取得する
    シート名=Excel.Worksheets(i).Name

    //エディタにシート名と内容を貼り付けて、改行する
    SendStr(エディタ,"******************************************************<#CR>")
    SendStr(エディタ,"★" +  シート名 + "★<#CR>")
    sckey(エディタ,vk_ctrl,vk_v)
    SendStr(エディタ,"<#CR>")
    sleep(0.01)    //0.01秒待たせます
next    //最後のExcelシートまで繰返す

Excel.Application.CutCopyMode = False
Excel.Worksheets(1).activate

//Excel画面というIDで、取得してあった、ウインドウズの画面としてのExcelを、前画面に表示します。
CtrlWin(Excel画面,activate)